diff --git a/priv/.gitignore b/priv/.gitignore
index 8f857fe..9ba068a 100644
--- a/priv/.gitignore
+++ b/priv/.gitignore
@@ -1 +1,2 @@
egs_drv.so
+patch.conf
diff --git a/priv/patch.conf b/priv/patch.conf
new file mode 100644
index 0000000..41e1eab
--- /dev/null
+++ b/priv/patch.conf
@@ -0,0 +1,25 @@
+%% This file is part of EGS.
+%%
+%% EGS is free software: you can redistribute it and/or modify
+%% it under the terms of the GNU Affero General Public License as
+%% published by the Free Software Foundation, either version 3 of the
+%% License, or (at your option) any later version.
+%%
+%% EGS is distributed in the hope that it will be useful,
+%% but WITHOUT ANY WARRANTY; without even the implied warranty of
+%% MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+%% GNU Affero General Public License for more details.
+%%
+%% You should have received a copy of the GNU Affero General Public License
+%% along with EGS. If not, see .
+
+%% @doc List of folders where patched files are located.
+{folders, [root, "DATA"]}.
+
+%% @doc Files in the root folder.
+{{folder, root}, [
+]}.
+
+%% @doc Files in the DATA folder.
+{{folder, "DATA"}, [
+]}.
diff --git a/priv/patch/.gitignore b/priv/patch/.gitignore
new file mode 100644
index 0000000..72e8ffc
--- /dev/null
+++ b/priv/patch/.gitignore
@@ -0,0 +1 @@
+*
diff --git a/priv/patch/patch-0.bin b/priv/patch/patch-0.bin
deleted file mode 100644
index 9f91ffb..0000000
Binary files a/priv/patch/patch-0.bin and /dev/null differ
diff --git a/priv/patch/patch-1.bin b/priv/patch/patch-1.bin
deleted file mode 100644
index 139dddb..0000000
--- a/priv/patch/patch-1.bin
+++ /dev/null
@@ -1 +0,0 @@
-ɲ|7[
\ No newline at end of file
diff --git a/priv/patch/patch-2.bin b/priv/patch/patch-2.bin
deleted file mode 100644
index 120cbcf..0000000
Binary files a/priv/patch/patch-2.bin and /dev/null differ
diff --git a/priv/patch/patch-3.bin b/priv/patch/patch-3.bin
deleted file mode 100644
index fff0cdd..0000000
--- a/priv/patch/patch-3.bin
+++ /dev/null
@@ -1 +0,0 @@
-ލE%5%
\ No newline at end of file
diff --git a/priv/patch/patch-4.bin b/priv/patch/patch-4.bin
deleted file mode 100644
index c79d6e7..0000000
--- a/priv/patch/patch-4.bin
+++ /dev/null
@@ -1,2 +0,0 @@
-;x6Z
-!U C(\ R$a6+FVx9x*+.tBw]3Rٌ
\ No newline at end of file
diff --git a/src/egs_patch_files_db.erl b/src/egs_patch_files_db.erl
new file mode 100644
index 0000000..aea698e
--- /dev/null
+++ b/src/egs_patch_files_db.erl
@@ -0,0 +1,172 @@
+%% @author Loc Hoguin
+%% @copyright 2010 Loc Hoguin.
+%% @doc EGS patch files database and cache manager.
+%%
+%% This file is part of EGS.
+%%
+%% EGS is free software: you can redistribute it and/or modify
+%% it under the terms of the GNU Affero General Public License as
+%% published by the Free Software Foundation, either version 3 of the
+%% License, or (at your option) any later version.
+%%
+%% EGS is distributed in the hope that it will be useful,
+%% but WITHOUT ANY WARRANTY; without even the implied warranty of
+%% MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+%% GNU Affero General Public License for more details.
+%%
+%% You should have received a copy of the GNU Affero General Public License
+%% along with EGS. If not, see .
+
+-module(egs_patch_files_db).
+-behavior(gen_server).
+-export([start_link/0, stop/0, list/0, check/3, get_size/1, get_info/1, reload/0]). %% API.
+-export([init/1, handle_call/3, handle_cast/2, handle_info/2, terminate/2, code_change/3]). %% gen_server.
+
+-include_lib("kernel/include/file.hrl").
+
+-record(state, {list_bin=[], files=[]}).
+-record(file, {crc, size, folder, filename_bin, full_filename}).
+
+%% Use the module name for the server's name.
+-define(SERVER, ?MODULE).
+
+%% API.
+
+%% @spec start_link() -> {ok,Pid::pid()}
+start_link() ->
+ gen_server:start_link({local, ?SERVER}, ?MODULE, [], []).
+
+%% @spec stop() -> stopped
+stop() ->
+ gen_server:call(?SERVER, stop).
+
+%% @spec list() -> binary()
+list() ->
+ gen_server:call(?SERVER, list).
+
+%% @spec check(FileNumber, CRC, Size) -> ok | invalid
+check(FileNumber, CRC, Size) ->
+ gen_server:call(?SERVER, {check, FileNumber, CRC, Size}).
+
+%% @spec get_size(FileNumber) -> Size
+get_size(FileNumber) ->
+ gen_server:call(?SERVER, {get_size, FileNumber}).
+
+%% @spec get_info(FileNumber) -> {CRC, Size, FilenameBin, FullFilename}
+get_info(FileNumber) ->
+ gen_server:call(?SERVER, {get_info, FileNumber}).
+
+%% @spec reload() -> ok
+reload() ->
+ gen_server:cast(?SERVER, reload).
+
+%% gen_server.
+
+init([]) ->
+ {ok, build_state()}.
+
+handle_call(list, _From, State=#state{list_bin=Bin}) ->
+ {reply, Bin, State};
+
+handle_call({check, FileNumber, CRC, Size}, _From, State=#state{files=Files}) ->
+ File = proplists:get_value(FileNumber, Files),
+ case File of
+ #file{crc=CRC, size=Size} -> {reply, ok, State};
+ _Any -> {reply, invalid, State}
+ end;
+
+handle_call({get_size, FileNumber}, _From, State=#state{files=Files}) ->
+ File = proplists:get_value(FileNumber, Files),
+ {reply, File#file.size, State};
+
+handle_call({get_info, FileNumber}, _From, State=#state{files=Files}) ->
+ {reply, proplists:get_value(FileNumber, Files), State};
+
+handle_call(stop, _From, State) ->
+ {stop, normal, stopped, State};
+
+handle_call(_Request, _From, State) ->
+ {reply, ignored, State}.
+
+handle_cast(reload, _State) ->
+ {noreply, build_state()};
+
+handle_cast(_Msg, State) ->
+ {noreply, State}.
+
+handle_info(_Info, State) ->
+ {noreply, State}.
+
+terminate(_Reason, _State) ->
+ ok.
+
+code_change(_OldVsn, State, _Extra) ->
+ {ok, State}.
+
+%% Internal.
+
+build_state() ->
+ {ok, Terms} = file:consult("priv/patch.conf"),
+ Folders = proplists:get_value(folders, Terms),
+ {ListBin, Files} = build_list_bin(Folders, Terms),
+ #state{list_bin=ListBin, files=Files}.
+
+%% The file number must start at 0.
+build_list_bin(Folders, Terms) ->
+ build_list_bin(Folders, Terms, 0, [], []).
+build_list_bin([], _Terms, _N, Acc, FilesAcc) ->
+ Bin = list_to_binary(lists:reverse(Acc)),
+ Bin2 = << 16#08:32/little, 16#06:32/little, Bin/binary, 16#08:32/little, 16#08:32/little >>,
+ {Bin2, lists:flatten(FilesAcc)};
+build_list_bin([Folder|Tail], Terms, N, Acc, FilesAcc) ->
+ Filenames = proplists:get_value({folder, Folder}, Terms),
+ {BinFiles, Files, N2} = build_files_bin(Folder, Filenames, N),
+ BinFiles2 = case Folder of
+ root -> BinFiles;
+ _Any ->
+ FolderBin = list_to_binary(Folder),
+ Padding = 8 * (64 - length(Folder)),
+ << 16#48:32/little, 16#09:32/little, FolderBin/binary, 0:Padding,
+ BinFiles/binary, 16#08:32/little, 16#0a:32/little >>
+ end,
+ build_list_bin(Tail, Terms, N2, [BinFiles2|Acc], [Files|FilesAcc]).
+
+build_files_bin(Folder, Filenames, N) ->
+ build_files_bin(Folder, Filenames, N, [], []).
+build_files_bin(_Folder, [], N, Acc, FilesAcc) ->
+ Bin = list_to_binary(lists:reverse(Acc)),
+ {Bin, FilesAcc, N};
+build_files_bin(Folder, [Filename|Tail], N, Acc, FilesAcc) ->
+ FullFilename = case Folder of
+ root -> ["priv/patch/"|Filename];
+ _Any -> ["priv/patch/",Folder,"/"|Filename]
+ end,
+ Size = file_get_size(FullFilename),
+ CRC = file_get_crc(FullFilename),
+ FilenameBin = list_to_binary(Filename),
+ Padding = 8 * (64 - length(Filename)),
+ FilenameBin2 = << FilenameBin/binary, 0:Padding >>,
+ Bin = << 16#4c:32/little, 16#07:32/little, N:32/little, FilenameBin2/binary >>,
+ build_files_bin(Folder, Tail, N + 1, [Bin|Acc], [{N, #file{crc=CRC, size=Size, folder=Folder, filename_bin=FilenameBin2, full_filename=FullFilename}}|FilesAcc]).
+
+file_get_size(Filename) ->
+ {ok, FileInfo} = file:read_file_info(Filename),
+ FileInfo#file_info.size.
+
+file_get_crc(Filename) ->
+ {ok, IoDevice} = file:open(Filename, [read, raw, binary]),
+ case file:read(IoDevice, 524288) of
+ eof -> 0;
+ {ok, Data} ->
+ CRC = erlang:crc32(Data),
+ file_get_crc(IoDevice, CRC)
+ end.
+file_get_crc(IoDevice, CRC) ->
+ case file:read(IoDevice, 524288) of
+ {ok, Data} ->
+ CRC2 = erlang:crc32(CRC, Data),
+ file_get_crc(IoDevice, CRC2);
+ eof ->
+ file:close(IoDevice),
+ CRC
+ end.
diff --git a/src/egs_patch_server.erl b/src/egs_patch_server.erl
new file mode 100644
index 0000000..2fcb89a
--- /dev/null
+++ b/src/egs_patch_server.erl
@@ -0,0 +1,234 @@
+%% @author Loc Hoguin
+%% @copyright 2010 Loc Hoguin.
+%% @doc Patch server module.
+%%
+%% This file is part of EGS.
+%%
+%% EGS is free software: you can redistribute it and/or modify
+%% it under the terms of the GNU Affero General Public License as
+%% published by the Free Software Foundation, either version 3 of the
+%% License, or (at your option) any later version.
+%%
+%% EGS is distributed in the hope that it will be useful,
+%% but WITHOUT ANY WARRANTY; without even the implied warranty of
+%% MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+%% GNU Affero General Public License for more details.
+%%
+%% You should have received a copy of the GNU Affero General Public License
+%% along with EGS. If not, see .
+
+-module(egs_patch_server).
+-export([start_link/1]). %% External.
+-export([listen/1, accept/1, init/1, recv/3]). %% Internal
+
+-define(OPTIONS, [binary, {active, true}, {packet, 0}, {reuseaddr, true}, {send_timeout, 5000}]).
+
+-record(state, {step=start, files=[]}).
+
+%% @spec start_link(Port) -> {ok,Pid::pid()}
+%% @doc Start the PSU patch server for inclusion in a supervisor tree.
+start_link(Port) ->
+ Pid = spawn(?MODULE, listen, [Port]),
+ {ok, Pid}.
+
+%% @spec listen(Port) -> ok
+%% @doc Listen for connections.
+listen(Port) ->
+ error_logger:info_report(io_lib:format("listener started for ~p on port ~b", [?MODULE, Port])),
+ {ok, LSocket} = gen_tcp:listen(Port, ?OPTIONS),
+ ?MODULE:accept(LSocket).
+
+%% @spec accept(LSocket) -> ok
+%% @doc Accept connections.
+accept(LSocket) ->
+ case gen_tcp:accept(LSocket, 5000) of
+ {ok, CSocket} ->
+ Pid = spawn(?MODULE, init, [CSocket]),
+ gen_tcp:controlling_process(CSocket, Pid);
+ {error, timeout} ->
+ reload
+ end,
+ ?MODULE:accept(LSocket).
+
+%% @spec init(CSocket) -> ok
+%% @doc Send the hello packet and move on to the main loop.
+init(CSocket) ->
+ send_01(CSocket),
+ recv(CSocket, << >>, #state{}).
+
+%% @spec recv(CSocket, SoFar, State) -> ok
+%% @doc Receive commands from the client and process them.
+recv(CSocket, SoFar, State) ->
+ receive
+ {tcp, CSocket, Data} ->
+ {Commands, Rest} = split(<< SoFar/bits, Data/bits >>, []),
+ case handle(CSocket, Commands, State) of
+ closed -> closed;
+ State2 -> ?MODULE:recv(CSocket, Rest, State2)
+ end;
+ {tcp_closed, CSocket} ->
+ tcp_closed;
+ {tcp_error, CSocket, _Any} ->
+ tcp_error;
+ _ ->
+ ?MODULE:recv(CSocket, SoFar, State)
+ end.
+
+%% @spec split(Bin, Acc) -> {Commands, Rest}
+%% @doc Split the given binary into a list of commands.
+split(<< >>, Acc) ->
+ {lists:reverse(Acc), << >>};
+split(Rest = << Size:32/little, Data/bits >>, Acc) when Data + 4 < Size ->
+ {lists:reverse(Acc), Rest};
+split(<< Size:32/little, Cmd:16/little, _Junk:16, Rest/bits >>, Acc) ->
+ BitSize = 8 * Size - 64,
+ << Data:BitSize/bits, Rest2/bits >> = Rest,
+ split(Rest2, [{command, Cmd, Size, Data}|Acc]).
+
+%% @spec handle(CSocket, CommandsList) -> closed | State
+%% @doc Handle the given commands.
+handle(_CSocket, [], State) ->
+ State;
+%% Start of file info reply.
+handle(CSocket, [{command, 16#0c, 8, << >>}|Tail], State=#state{step=waitfileinfo}) ->
+ handle(CSocket, Tail, State#state{step=recvfileinfo});
+%% File info.
+handle(CSocket, [{command, 16#0d, 20, << FileNumber:32/little, CRC:32/little, Size:32/little >>}|Tail], State=#state{step=recvfileinfo}) ->
+ State2 = case egs_patch_files_db:check(FileNumber, CRC, Size) of
+ ok -> State;
+ invalid -> State#state{files=[FileNumber|State#state.files]}
+ end,
+ handle(CSocket, Tail, State2);
+%% End of file info reply. Nothing expected from the client afterward.
+handle(CSocket, [{command, 16#0e, 8, << >>}], #state{step=recvfileinfo, files=Files}) ->
+ case Files of
+ [] -> ok; %% No files to update.
+ _List -> update(CSocket, lists:reverse(Files))
+ end,
+ send_13(CSocket),
+ closed;
+%% Hello reply.
+%% @todo Figure out the remaining unknown values.
+handle(CSocket, [{command, 16#14, 52, << 16#e44c0915:32, UnknownA:32/little, UnknownB:32/little, UnknownC:32/little,
+ UnknownD:32/little, _GameVersion:32/little, UnknownE:32/little, 0:128 >>}|Tail], State=#state{step=start}) ->
+ io:format("patch #14: ~p ~p ~p ~p ~p~n", [UnknownA, UnknownB, UnknownC, UnknownD, UnknownE]),
+ ListBin = egs_patch_files_db:list(),
+ gen_tcp:send(CSocket, ListBin),
+ handle(CSocket, Tail, State#state{step=waitfileinfo});
+%% Unknown command.
+handle(_CSocket, [{command, Cmd, _Size, Data}|_Tail], State) ->
+ io:format("~p: dismissed command ~2.16.0b - ~p - ~p~n", [?MODULE, Cmd, Data, State]),
+ closed.
+
+%% @spec update(CSocket, Files) -> ok
+%% @doc Update the invalid client files.
+update(CSocket, Files) ->
+ Size = update_size(Files),
+ send_0f(CSocket, Size, length(Files)),
+ update_files(CSocket, root, Files).
+
+%% @spec update_files(CSocket, Files) -> ok
+%% @doc Send all the files the client needs to update.
+update_files(_CSocket, _CurrentFolder, []) ->
+ ok;
+update_files(CSocket, CurrentFolder, [FileNumber|Tail]) ->
+ {file, _CRC, Size, Folder, FilenameBin, FullFilename} = egs_patch_files_db:get_info(FileNumber),
+ case CurrentFolder of
+ Folder -> ok;
+ _Any ->
+ if CurrentFolder =/= root ->
+ send_0a(CSocket);
+ true -> ok
+ end,
+ if Folder =/= root ->
+ send_09(CSocket, Folder);
+ true -> ok
+ end
+ end,
+ send_10(CSocket, Size, FilenameBin),
+ update_send_file(CSocket, FullFilename),
+ send_12(CSocket),
+ update_files(CSocket, Folder, Tail).
+
+%% @spec update_send_file(CSocket, Filename) -> ok
+%% @doc Send a file by fragmenting it into many chunks of fixed size.
+update_send_file(CSocket, Filename) ->
+ {ok, IoDevice} = file:open(Filename, [read, raw, binary]),
+ update_send_file(CSocket, IoDevice, 0).
+update_send_file(CSocket, IoDevice, N) ->
+ case file:read(IoDevice, 24576) of
+ {ok, Data} ->
+ send_11(CSocket, Data, N),
+ update_send_file(CSocket, IoDevice, N + 1);
+ eof ->
+ file:close(IoDevice)
+ end.
+
+%% @spec update_size(Files) -> Size
+%% @doc Return the total size for all the files given.
+update_size(Files) ->
+ update_size(Files, 0).
+update_size([], Size) ->
+ Size;
+update_size([FileNumber|Tail], Size) ->
+ FileSize = egs_patch_files_db:get_size(FileNumber),
+ update_size(Tail, Size + FileSize).
+
+%% @spec send_01(CSocket) -> ok
+%% @doc Hello command sent when a client connects to the server. Encryption is disabled.
+send_01(CSocket) ->
+ Bin = << 16#28:32/little, 16#01:32/little, 16#8b9f2dfa:32, 0:96, 1:32/little, 0:96 >>,
+ gen_tcp:send(CSocket, Bin).
+
+%% @spec send_09(CSocket, Folder) -> ok
+%% @doc Change folder command.
+send_09(CSocket, Folder) ->
+ FolderBin = list_to_binary(Folder),
+ Padding = 8 * (64 - length(Folder)),
+ Bin = << 16#48:32/little, 16#09:32/little, FolderBin/binary, 0:Padding >>,
+ gen_tcp:send(CSocket, Bin).
+
+%% @spec send_0a(CSocket) -> ok
+%% @doc Back to root folder command.
+send_0a(CSocket) ->
+ Bin = << 16#8:32/little, 16#0a:32/little >>,
+ gen_tcp:send(CSocket, Bin).
+
+%% @spec send_0f(CSocket, TotalSize, NbFiles) -> ok
+%% @doc General update information command. Prepare the update screen.
+send_0f(CSocket, Size, NbFiles) ->
+ Bin = << 16#10:32/little, 16#0f:32/little, Size:32/little, NbFiles:32/little >>,
+ gen_tcp:send(CSocket, Bin).
+
+%% @spec send_10(CSocket, Size, FilenameBin) -> ok
+%% @doc File update begin command. Prepare sending an individual file.
+send_10(CSocket, Size, FilenameBin) ->
+ Bin = << 16#50:32/little, 16#10:32/little, 0:32, Size:32/little, FilenameBin/binary >>,
+ gen_tcp:send(CSocket, Bin).
+
+%% @spec send_11(CSocket, Data, N) -> ok
+%% @doc Command to send a file fragment.
+send_11(CSocket, Data, N) ->
+ DataSize = byte_size(Data),
+ Padding = case DataSize rem 4 of
+ 0 -> 0;
+ Rem -> 8 * (4 - Rem)
+ end,
+ Data2 = << Data/binary, 0:Padding >>,
+ DataSize2 = DataSize + Padding div 8,
+ Size = DataSize2 + 16#14,
+ CRC = erlang:crc32(Data2),
+ Bin = << Size:32/little, 16#11:32/little, N:32/little, CRC:32/little, DataSize:32/little, Data2/binary >>,
+ gen_tcp:send(CSocket, Bin).
+
+%% @spec send_12(CSocket) -> ok
+%% @doc File update end command.
+send_12(CSocket) ->
+ Bin = << 16#8:32/little, 16#12:32/little >>,
+ gen_tcp:send(CSocket, Bin).
+
+%% @spec send_13(CSocket) -> ok
+%% @doc Update complete command. Usually followed by the server closing the connection.
+send_13(CSocket) ->
+ Bin = << 16#8:32/little, 16#13:32/little >>,
+ gen_tcp:send(CSocket, Bin).
diff --git a/src/egs_sup.erl b/src/egs_sup.erl
index cadc518..0147a8c 100644
--- a/src/egs_sup.erl
+++ b/src/egs_sup.erl
@@ -51,13 +51,14 @@ init([]) ->
PatchPorts = egs_conf:read(patch_ports),
LoginPorts = egs_conf:read(login_ports),
{_ServerIP, GamePort} = egs_conf:read(game_server),
- PatchProcs = [{{egs_patch_server, Port}, {psu_patch, start_link, [Port]}, permanent, 5000, worker, dynamic} || Port <- PatchPorts],
+ PatchProcs = [{{egs_patch_server, Port}, {egs_patch_server, start_link, [Port]}, permanent, 5000, worker, dynamic} || Port <- PatchPorts],
LoginProcs = [{{egs_login_server, Port}, {egs_login_server, start_link, [Port]}, permanent, 5000, worker, dynamic} || Port <- LoginPorts],
OtherProcs = [
{egs_seasons, {egs_seasons, start_link, []}, permanent, 5000, worker, dynamic},
{egs_counters_db, {egs_counters_db, start_link, []}, permanent, 5000, worker, dynamic},
{egs_items_db, {egs_items_db, start_link, []}, permanent, 5000, worker, dynamic},
{egs_npc_db, {egs_npc_db, start_link, []}, permanent, 5000, worker, dynamic},
+ {egs_patch_files_db, {egs_patch_files_db, start_link, []}, permanent, 5000, worker, dynamic},
{egs_quests_db, {egs_quests_db, start_link, []}, permanent, 5000, worker, dynamic},
{egs_shops_db, {egs_shops_db, start_link, []}, permanent, 5000, worker, dynamic},
{egs_accounts, {egs_accounts, start_link, []}, permanent, 5000, worker, dynamic},
diff --git a/src/psu/psu_patch.erl b/src/psu/psu_patch.erl
deleted file mode 100644
index e10825d..0000000
--- a/src/psu/psu_patch.erl
+++ /dev/null
@@ -1,67 +0,0 @@
-%% @author Loc Hoguin
-%% @copyright 2010 Loc Hoguin.
-%% @doc Process patch requests.
-%%
-%% This file is part of EGS.
-%%
-%% EGS is free software: you can redistribute it and/or modify
-%% it under the terms of the GNU Affero General Public License as
-%% published by the Free Software Foundation, either version 3 of the
-%% License, or (at your option) any later version.
-%%
-%% EGS is distributed in the hope that it will be useful,
-%% but WITHOUT ANY WARRANTY; without even the implied warranty of
-%% MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
-%% GNU Affero General Public License for more details.
-%%
-%% You should have received a copy of the GNU Affero General Public License
-%% along with EGS. If not, see .
-
--module(psu_patch).
--export([start_link/1]). %% External.
--export([listen/1, accept/1, process/1]). %% Internal
-
--define(OPTIONS, [binary, {send_timeout, 5000}, {packet, 0}, {active, false}, {reuseaddr, true}]).
-
-%% @spec start_link(Port) -> {ok,Pid::pid()}
-%% @doc Start the PSU patch server for inclusion in a supervisor tree.
-start_link(Port) ->
- Pid = spawn(?MODULE, listen, [Port]),
- {ok, Pid}.
-
-%% @spec listen(Port) -> ok
-%% @doc Listen for connections.
-listen(Port) ->
- error_logger:info_report(io_lib:format("psu_patch listening on port ~b", [Port])),
- {ok, LSocket} = gen_tcp:listen(Port, ?OPTIONS),
- ?MODULE:accept(LSocket).
-
-%% @spec accept(LSocket) -> ok
-%% @doc Accept connections.
-accept(LSocket) ->
- case gen_tcp:accept(LSocket, 5000) of
- {ok, CSocket} ->
- spawn(?MODULE, process, [CSocket]);
- {error, timeout} ->
- reload
- end,
- ?MODULE:accept(LSocket).
-
-%% @spec process(CSocket) -> ok
-%% @doc Fake the patch server by sending what the game wants to hear: no updates available.
-process(CSocket) ->
- io:format("faking patch server: no updates~n"),
- send_packet(CSocket, "priv/patch/patch-0.bin"),
- gen_tcp:recv(CSocket, 0, 5000),
- send_packet(CSocket, "priv/patch/patch-1.bin"),
- send_packet(CSocket, "priv/patch/patch-2.bin"),
- gen_tcp:recv(CSocket, 0, 5000),
- send_packet(CSocket, "priv/patch/patch-3.bin"),
- send_packet(CSocket, "priv/patch/patch-4.bin"),
- gen_tcp:close(CSocket).
-
-%% @spec send_packet(CSocket, PacketFilename) -> ok
-%% @doc Send a packet from a file.
-send_packet(CSocket, PacketFilename) ->
- {ok, Packet} = file:read_file(PacketFilename),
- gen_tcp:send(CSocket, Packet).